Distance sensing with ultrasonic sensor and Arduino

Plugging in the sensor

  • VCC -> Arduino +5V pin
  • GND -> Arduino GND pin
  • Trig -> Arduino Digital Pin 2
  • Echo -> Arduino Digital Pin 2

The Trig pin will be used to send the signal and the Echo pin will be used to listen for returning signal.

After my messy wiring the end assembly looked like this:

End sensor assembly

Getting data from the sensor

The code is fairly straightforward. I took the original example code for Ping))) sensor and just modified the OUTPUT pin to be Digital Pin 2, the INPUT pin to be Digital Pin 4 and trigger duration to 10 us.

/* HC-SR04 Sensor
http://www.desensed.com/sensors/31-hc-sr04-ultrasonicsonar-distance-sensor-module.html


This sketch reads a HC-SR04 ultrasonic rangefinder and returns the
distance to the closest object in range. To do this, it sends a pulse
to the sensor to initiate a reading, then listens for a pulse
to return. The length of the returning pulse is proportional to
the distance of the object from the sensor.

The circuit:
* VCC connection of the sensor attached to +5V
* GND connection of the sensor attached to ground
* TRIG connection of the sensor attached to digital pin 2
* ECHO connection of the sensor attached to digital pin 4


Original code for Ping))) example was created by David A. Mellis
Adapted for HC-SR04 by Tautvidas Sipavicius

This example code is in the public domain.
*/


const int trigPin = 2;
const int echoPin = 4;

void setup() {
// initialize serial communication:
Serial.begin(9600);
}

void loop()
{
// establish variables for duration of the ping,
// and the distance result in inches and centimeters:
long duration, inches, cm;

// The sensor is triggered by a HIGH pulse of 10 or more microseconds.
// Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
pinMode(trigPin, OUTPUT);
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH);
delayMicroseconds(10);
digitalWrite(trigPin, LOW);

// Read the signal from the sensor: a HIGH pulse whose
// duration is the time (in microseconds) from the sending
// of the ping to the reception of its echo off of an object.
pinMode(echoPin, INPUT);
duration = pulseIn(echoPin, HIGH);

// convert the time into a distance
inches = microsecondsToInches(duration);
cm = microsecondsToCentimeters(duration);

Serial.print(inches);
Serial.print("in, ");
Serial.print(cm);
Serial.print("cm");
Serial.println();

delay(100);
}

long microsecondsToInches(long microseconds)
{
// According to Parallax's datasheet for the PING))), there are
// 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
// second). This gives the distance travelled by the ping, outbound
// and return, so we divide by 2 to get the distance of the obstacle.
// See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds)
{
// The speed of sound is 340 m/s or 29 microseconds per centimeter.
// The ping travels out and back, so to find the distance of the
// object we take half of the distance travelled.
return microseconds / 29 / 2;
}

view rawhc-sr04.ino hosted with ❤ by GitHub

After compiling, uploading and running it, in the Serial Monitor (Tools -> Serial Monitoror Ctrl + Shift + M) the sensor was sending correct data!

Result

Sensor sending correct data

After a bit of fooling around I found out that the range is approximately 2cm - 300cm. Which is not bad, but not perfect either.